zsh에서 LS_COLORS 테스트

몇 년 전에 설정 한 색상에 따라 각 유형의 파일을 해당 색상으로 인쇄하는 흥미로운 코드 스 니펫을 발견했습니다 LS_COLORS. 불행히도 더 이상 링크를 기억할 수 없습니다.

test_colors.sh문제 의 스 니펫은 다음과 같습니다.

eval $(echo "no:global default;fi:normal file;di:directory;ln:symbolic link;pi:named pipe;so:socket;do:door;bd:block device;cd:character device;or:orphan symlink;mi:missing file;su:set uid;sg:set gid;tw:sticky other writable;ow:other w\
ritable;st:sticky;ex:executable;"|sed -e 's/:/="/g; s/\;/"\n/g')                                                                                                                                                                            
{                                                                                                                                                                                                                                           
  IFS=:                                                                                                                                                                                                                                     
  for i in $LS_COLORS                                                                                                                                                                                                                       
  do                                                                                                                                                                                                                                        
    echo -e "\e[${i#*=}m$( x=${i%=*}; [ "${!x}" ] && echo "${!x}" || echo "$x" )\e[m"                                                                                                                                                       
  done                                                                                                                                                                                                                                      
}   

이 스 니펫은에서 잘 작동 bash하지만 에서 작동 zsh하지 않으며 그 이유를 알 수 없습니다. 실행할 때 zsh다음 오류가 발생합니다.

> sh .test_colors.sh
.eval_colors:1: * not found
[00:fi=00:di=01;34:ln=01;36:pi=40;33:so=01;35:do=01;35:bd=40;33;01:cd=40;33;01:or=40;31;01:su=37;41:sg=30;43:tw=30;42:ow=34;42:st=37;44:ex=01;32:*.tar=01;31:*.tgz=01;31:*.arj=01;31:*.taz=01;31:*.lzh=01;31:*.zip=01;31:*.z=01;31:*.Z=01;31:*.gz=01;31:*.bz2=01;31:*.deb=01;31:*.rpm=01;31:*.jar=01;31:*.jpg=01;35:*.jpeg=01;35:*.gif=01;35:*.bmp=01;35:*.pbm=01;35:*.pgm=01;35:*.ppm=01;35:*.tga=01;35:*.xbm=01;35:*.xpm=01;35:*.tif=01;35:*.tiff=01;35:*.png=01;35:*.mov=01;35:*.mpg=01;35:*.mpeg=01;35:*.avi=01;35:*.fli=01;35:*.gl=01;35:*.dl=01;35:*.xcf=01;35:*.xwd=01;35:*.flac=01;35:*.mp3=01;35:*.mpc=01;35:*.ogg=01;35:*.wav=01;35:m

업데이트 (2011 년 11 월 1 일)

아래 @ Stéphane Gimenez의 스크립트를 테스트했습니다. 일부 문자가 올바르게 이스케이프되지 않은 것으로 나타났습니다. 왜 생각해?

답변 : @ Stéphane Gimenez 님의 답변에 대한 의견을 참조하십시오.

훨씬 더 깔끔한 방식으로 zsh 용으로 작성되었습니다.

#!/bin/zsh

typeset -A names
names[no]="global default"
names[fi]="normal file"
names[di]="directory"
names[ln]="symbolic link"
names[pi]="named pipe"
names[so]="socket"
names[do]="door"
names[bd]="block device"
names[cd]="character device"
names[or]="orphan symlink"
names[mi]="missing file"
names[su]="set uid"
names[sg]="set gid"
names[tw]="sticky other writable"
names[ow]="other writable"
names[st]="sticky"
names[ex]="executable"

for i in ${(s.:.)LS_COLORS}
do
    key=${i%\=*}
    color=${i#*\=}
    name=${names[(e)$key]-$key}
    printf '\e[%sm%s\e[m\n' $color $name
done

그렇지 않으면 접미사 패턴 이 확장 되어 명령 이름으로 해석 되므로 =in 을 이스케이프해야합니다 . 이것이 오류 의 원인입니다 .${i%=*}=*==* not found

Zsh는 기본적으로 변수 대체에서 단어를 분리하지 않으므로 $LS_COLORS단일 단어로 확장됩니다. for의 콜론으로 구분 된 부분 에서 루프를 작동 시키려면을 $LS_COLORS사용하십시오 for i in $=LS_COLORS. 또는 zsh에서 관용적으로 사용 IFS하지 말고 대신 분할 방법을 명시 적으로 지정하십시오 for i in ${(s.:.)LS_COLORS}.

${!x}"이름이 변수의 값"을 의미 하는 구문 $x은 bash에만 해당됩니다. zsh을 동등한 구조체의 보유 P 파라미터 확장 플래그 : ${(P)x}.