더 나은 붙여 넣기 명령

다음 두 파일이 있습니다 (파일의 모든 줄이 같은 너비가되도록 file1을 모두 대문자로 지정하여 더 명확하게하기 위해 점으로 선을 채웠습니다).

contents of file1:

ETIAM......
SED........
MAECENAS...
DONEC......
SUSPENDISSE

contents of file2

Lorem....
Proin....
Nunc.....
Quisque..
Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

file2가 file1보다 깁니다.

이 명령을 실행할 때 :

paste file1 file2

이 결과를 얻습니다

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
    Nam......
    Vivamus..
    Curabitur
    Nullam...

출력을 다음과 같이하려면 어떻게해야합니까?

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
            Nam......
            Vivamus..
            Curabitur
            Nullam...

나는 시도했다

paste file1 file2 | column -t

그러나 이것은 이렇게합니다 :

ETIAM......  Lorem....
SED........  Proin....
MAECENAS...  Nunc.....
DONEC......  Quisque..
SUSPENDISSE  Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

어쨌든 원래 출력만큼 ​​추악하지는 않지만 열 방향으로 잘못되었습니다.

파일에 탭 문자가 없다고 가정하면,

paste file1 file2 | expand -t 13

-tfile1에서 원하는 최대 행 너비를 포함 하도록 arg를 적절하게 선택합니다.

OP는보다 유연한 솔루션을 추가했습니다.

나는 이것을 마법의 숫자 13없이 작동하도록했다.

paste file1 file2 | expand -t $(( $(wc -L <file1) + 2 ))

입력하기 쉽지 않지만 스크립트에서 사용할 수 있습니다.

나는 awk가 잘 할 것이라고 생각했기 때문에 "두 개의 파일에서 입력을 읽는 중"을 Google 로 검색하고 stackoverflow 에 대한 기사를 시작점으로 사용했습니다.

첫 번째는 압축 버전이며 그 아래에 완전히 주석이 달렸습니다. 운동하는 데 몇 분 이상이 걸렸습니다. 더 똑똑한 사람들의 개선점에 기뻐할 것입니다.

awk '{if(length($0)>max)max=length($0)}
FNR==NR{s1[FNR]=$0;next}{s2[FNR]=$0}
END { format = "%-" max "s\t%-" max "s\n";
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) { printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:"" }
}' file1 file2

그리고 여기에 위의 완전한 문서화 된 버전이 있습니다.

# 2013-11-05 mike@diehn.net
# Invoke thus:
#   awk -f this_file file1 file2
# The result is what you asked for and the columns will be
# determined by input file order.
#----------------------------------------------------------
# No matter which file we're reading,
# keep track of max line length for use
# in the printf format.
#
{ if ( length($0) > max ) max=length($0) }

# FNR is record number in current file
# NR is record number over all
# while they are equal, we're reading the first file
#   and we load the strings into array "s1"
#   and then go to the "next" line in the file we're reading.
FNR==NR { s1[FNR]=$0; next }

# and when they aren't, we're reading the
#   second file and we put the strings into
#   array s2
{s2[FNR]=$0}

# At the end, after all lines from both files have
# been read,
END {
  # use the max line length to create a printf format
  # the right widths
  format = "%-" max "s\t%-" max "s\n"
  # and figure the number of array elements we need
  # to cycle through in a for loop.
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) {
     printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:""
  }
}

아주 좋은 해결책은 아니지만 사용하여 할 수있었습니다.

paste file1 file2 | sed 's/^TAB/&&/'

여기서 TAB은 탭 문자로 바뀝니다.

데비안과 파생물 column에는 열이 빈 필드로 올바른 일을 할 수 있도록 -n nomerge 옵션이 있습니다. 내부적 으로 넓은 문자열을 인수 의 넓은 문자로 구분 된 토큰으로 나누는 함수를 column사용합니다 .wcstok(wcs, delim, ptr)delim

wcstokdelim토큰을 인식하기 전에 에서 넓은 문자를 건너 뛰어 시작합니다 . 이 -n옵션은의 초기 와이드 문자를 건너 뛰지 않는 알고리즘을 사용합니다 delim.

불행히도, 이것은 이식성이 좋지 않습니다 : -n데비안 전용이며 columnPOSIX에는 없으며 BSD 일 것입니다.

패딩에 사용한 점 제거

file1 :

ETIAM
SED
MAECENAS
DONEC
SUSPENDISSE

file2 :

Lorem
Proin
Nunc
Quisque
Aenean
Nam
Vivamus
Curabitur
Nullam

이 시도:

$ ( echo ".TS"; echo "l l."; paste file1 file2; echo ".TE" ) | tbl | nroff | more

그리고 당신은 얻을 것이다 :

ETIAM         Lorem
SED           Proin
MAECENAS      Nunc
DONEC         Quisque
SUSPENDISSE   Aenean
              Nam
              Vivamus
              Curabitur
              Nullam

awk상당히 휴대해야하고, 입력 파일의 임의의 수에 대해 작동한다 용액 :

# Invoke thus:
#   awk -F\\t -f this_file file1 file2

# every time we read a new file, FNR goes to 1

FNR==1 {
    curfile++                       # current file
}

# read all files and save all the info we'll need
{
    column[curfile,FNR]=$0          # save current line
    nlines[curfile]++               # number of lines in current file
    if (length > len[curfile])
            len[curfile] = length   # max line length in current file
}

# finally, show the lines from all files side by side, as a table
END {
    # iterate through lines until there are no more lines in any file
    for (line = 1; !end; line++) {
            $0 = _
            end = 1

            # iterate through all files, we cannot use
            #   for (file in nlines) because arrays are unordered
            for (file=1; file <= curfile; file++) {
                    # columnate corresponding line from each file
                    $0 = $0 sprintf("%*s" FS, len[file], column[file,line])
                    # at least some file had a corresponding line
                    if (nlines[file] >= line)
                            end = 0
            }

            # don't print a trailing empty line
            if (!end)
                    print
    }
}