Vim에서 실행 취소 세분성을 변경하는 방법은 무엇입니까?

어떤 시점에서 내 Vim은 내가 맞을 때 전체 단어를 취소합니다 u.

[i]typing some words[C-c][u]

결과

typing some

그러나 실행 취소 세분성은 한 번에 하나의 문자를 삭제하는 것으로 변경되었습니다.

[i]typing some words[C-c][u]

결과

typing some word

Practical Vim에서 실행 취소 세분성을 사용자 정의하는 것에 대해 읽은 것을 기억하지만 제어 방법을 기억할 수는 없습니다. 어떤 도움을 주셔서 감사합니다!

실행 취소 시퀀스를 수동으로 끊기

을 사용하여 삽입 모드에서 실행 취소 시퀀스를 수동으로 해제 할 수 있습니다 <C-G>u. 에서 도움 :

CTRL-G u        break undo sequence, start new change

예

iHello<C-G>u world!<Esc>u

이것은 당신에게 텍스트를 남길 것입니다

Hello

명령 분석

i                           " Enter Insert mode
 Hello                      " Type 'Hello'
      <C-G>u                " Break the undo sequence
             world!         " Type ' world!'
                   <Esc>    " Return to Normal mode
                        u   " Undo

자동 솔루션

세밀한 실행 취소 레벨 제어

다음은 텍스트 삭제를 시작할 때와 삭제 후 다시 텍스트를 입력 할 때 실행 취소 나누기를 만드는 데 사용 되는 VimScript 의 작은 조각입니다<C-G>u .

function! s:start_delete(key)
    let l:result = a:key
    if !s:deleting
        let l:result = "\<C-G>u".l:result
    endif
    let s:deleting = 1
    return l:result
endfunction

function! s:check_undo_break(char)
    if s:deleting
        let s:deleting = 0
        call feedkeys("\<BS>\<C-G>u".a:char, 'n')
    endif
endfunction

augroup smartundo
    autocmd!
    autocmd InsertEnter * let s:deleting = 0
    autocmd InsertCharPre * call s:check_undo_break(v:char)
augroup END

inoremap <expr> <BS> <SID>start_delete("\<BS>")
inoremap <expr> <C-W> <SID>start_delete("\<C-W>")
inoremap <expr> <C-U> <SID>start_delete("\<C-U>")

노트

이것은 작동합니다 <BS>, <C-W>(단어를 삭제)하고, <C-U>(라인의 시작으로 삭제). 삽입 모드에서 삭제하는 방법이 더 있으면 inoremap끝에 통화를 추가하여 지원할 수 있습니다 .