이 <Esc> 일반 모드 매핑이 시작에 영향을주는 이유는 무엇입니까?

의 일반 모드 매핑에 이상한 문제가 Esc있습니다.

escmapvimrc내용으로 파일을 작성하는 경우 :

set nocompatible
set showcmd " Doesn't affect the problem: just makes it easier to see
nnoremap <Esc> :noh<CR><esc>

그런 다음이 vimrc를 사용하여 vim을 시작하십시오.

vim --noplugin -u escmapvimrc

그런 다음 vim은 c추가 입력을 기다리는 명령, 빈 파일 표시 및 명령 줄 표시와 함께 운영자 보류 모드로 시작 :noh합니다.

nnoremap라인 을 제거하면 문제가 해결됩니다.

모든 것을 디버그하고 단계별로 실행하면 다음과 같은 결과가 나타납니다.

Entering Debug mode.  Type "cont" to continue.
/[...]/escmapvimrc
line 1: set nocompatible
>s
/[...]/escmapvimrc
line 2: set showcmd " Doesn't affect the problem: just makes it easier to see
>s
/[...]/escmapvimrc
line 3: nnoremap <Esc> :noh<CR><esc>
>s
/[...]/escmapvimrc
line 4: End of sourced file
>s
Press ENTER or type command to continue

enter를 누르면 Vim 시작 화면이 아래에 표시됩니다.

Entering Debug mode.  Type "cont" to continue.
cmd: noh
>s

Vim 시작 화면이 사라지고 위에서 설명한대로 운영자 대기 모드에있게됩니다.

무슨 일이야?

편집 : 동작은 Vim 7.3에 설명되어 있습니다. Vim 7.4.52에서 nmap파일없이 Vim을 시작할 때 Vim이 Replace 모드로 시작됩니다. (빔 7.4.52이 시작되면 함께 파일, 그러나, 그것은 또한 진행 제왕 명령으로 시작됩니다.) 어느 쪽의 방법은 nmap을 제거 할 때 문제가 사라집니다.

Vim은 시작하는 동안 몇 가지 특수한 코드 (보통 <esc>키가 포함되어 있음 )를 보내 여러 가지 (색상, bs, ...)를 결정합니다. 매핑 한 경우 <esc>반환 코드 파서를 혼동 할 수 있으며 이상한 일이 발생할 수 있습니다.

따라서 모든 것이 올바르게 설정된 후에 만 ​​위의지도를 사용하십시오 (예 : VimEnter 자동 명령을 통해).

Linux 터미널은 ANSI 이스케이프 시퀀스 (예 :로 시작하는 문자열 <Esc>)를 사용하여 특수 키를 Vim에 보내고 응용 프로그램이 해당 기능을 쿼리하는 통신 프로토콜의 일부로 사용합니다. 매핑이이를 방해하여 이러한 "이상한"동작이 발생합니다.

따라서을 매핑하지 마십시오<Esc> . 다른 키를 사용하십시오. GVIM에서는 문제가 덜 두드러 지지만 권장하지는 않습니다.

이 시도:

augroup escape_mapping
  autocmd TermResponse * nnoremap <Esc> :noh<CR><esc>
augroup end

cf /programming//a/16027716/400545

나중에 시작할 때 매핑을 설정하기 위해 자동 명령을 설정하려고 시도했지만 여전히 문제가 발생했습니다. ^*

삽입 모드를 처음 시작할 때 자동 명령을 생성했습니다. 이것은 분명히 완벽한 솔루션은 아니지만 대부분의 경우 작동하며 최선을 다하는 것 같습니다.

업데이트 : 몇 년 동안 문제없이 아래 더 긴 버전을 사용한 후 약간 과도하게 엔지니어링 된 것으로 판단한 다음이 훨씬 더 간단한 버전을 사용하여 삽입 모드로 들어갈 때마다 매핑을 재설정합니다.

augroup escape_mapping
  autocmd!
  autocmd InsertEnter * call s:setupEscapeMap()
augroup END

function! s:setupEscapeMap()
  nnoremap <Esc> :noh<CR><Esc>
endfunction

삽입 모드로 들어갈 때마다 매핑을 재설정 할 필요 는 없지만 Vim이 그렇게하기 위해 해를 끼치 지 않습니다.

원래 버전 :

if !exists('g:escape_mapped')  " Only need to set the mapping up once.
  augroup escape_mapping
    autocmd!
    " Create the autocommand, to fire when Insert mode is entered
    autocmd InsertEnter * call s:setupEscapeMap()
  augroup END
endif

function! s:setupEscapeMap()
  " Actually create the mapping
  nnoremap <Esc> :noh<CR><Esc> 

  " Now the map exists, so we won't ever need the autocommand again.
  let g:escape_mapped = 1

  " Tidy up the autocommand and group
  autocmd! escape_mapping InsertEnter *
  augroup! escape_mapping
endfunction

^{* 나는 다양한 이벤트에 부착 시도 VimEnter, BufReadPost, BufWinEnter, 심지어 CursorMoved(!)하지만, 이러한 모든 너무 일찍 불에 보인다.}