인터리빙 라인으로 블록 병합

다음과 같이 줄을 인터리빙하여 두 개의 텍스트 블록을 병합하는 전용 방법이 있습니까?

a1
a2
a3
a4
  b1
  b2
  b3
  b4

그것에 :

a1
  b1
a2
  b2
a3
  b3
a4
  b4

몇 가지 명령으로?

편집 : Sato Katsura의 솔루션이 정말 마음에 듭니다 . 구현 방법은 다음과 같습니다.

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

그것을하는 전용 방법은 없지만 (아는 한) 몇 가지 명령으로 수행 할 수 있습니다.

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

로 실행할 수 있습니다 :call Interleave(5, 8, 1). 첫 번째 매개 변수는 이동할 첫 번째 행이고 두 번째 매개 변수는 마지막 행이며 세 번째 매개 변수는 이동할 행입니다. 행 번호를 켜서 수행중인 작업을 확인하고 싶을 것입니다 ( :set number).

블록이 겹치지 않는다고 가정합니다. 참조 :help :move및 :help range()기능 작동 방식을 이해 할 수 있습니다.

두 블록을 집어 올리는 더 좋은 방법이있을 것입니다. 두 블록을 교환 할 수있는 플러그인이 떠 있습니다. 나는 플러그인의 이름을 기억할 수 없지만 저자 (아마 유명한 Dr. Chip?)는 인터페이스를 찾는 것보다 더 많은 생각을했습니다. :)

다른 대안이 있습니다.

:g/^a/+4t .
:+,+5d 

먼저 현재 라인 (후 아래 4 개 라인은 라인 복사 :h :t)을 (B 연속 라인을 삭제 :h :d)

이 명령이 더 좋습니다.

 :g/^a//^\s*b/m .

즉, 시작으로 시작하는 각 줄에 대해 'b'로 시작하는 다음 줄을 찾아 현재 줄 아래로 이동하십시오.

매크로와 마크로 약간의 재미를 원한다면 다음과 같이 시도해보십시오.

• 먼저 와 함께 a포함 된 줄에 마크 (여기 )를 넣으십시오.a1ma

• 포함하는 행으로 이동 b1과 함께 표시mb

• 원하는 레지스터 (여기서 레지스터 q) 에서 매크로 기록을 시작하십시오.qq

• 매크로에 다음을 삽입하십시오. ddmb'apjma'b

• 로 매크로 기록 중지 q

• 재생 시간은 X@q어디에서 필요한만큼 X재생하십시오.

매크로를 자세히 설명하려면

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

설명에서 lago-lito가 언급했듯이이 방법은 마크와 버퍼를 덮어 씁니다.

• 나는 그것이 진짜 문제라고 생각하지 않는다. 나는 버퍼에 26 개의 마크를 거의 사용하지 않으며 대부분 2 개의 프리 마크를 찾게 될 것이라고 생각한다.

• 버퍼의 경우 임시 변수 :let saveReg=getreg('"')에 저장할 수 있습니다. 매크로를 기록하기 전에 레지스터를 저장하고 동작이 완료 :call setreg('"', saveReg)되면 레지스터를 이전 상태로 되 돌리는 데 사용 합니다.

어쨌든 나는이 솔루션이 빠른 해결 방법이며 최적이 아니라는 것을 인정해야합니다. 제 생각에 Christan의 대답 은 가장 좋으며 버퍼와 마크를 엉망으로 만들지 않기 때문에 받아 들여야합니다. 사용자가 만들지 마십시오. 함수와 전역 명령의 힘을 보여줍니다.

방금 다른 유사한 질문을 보았 으며 솔루션은 다음으로 구성됩니다.

중간 더하기 1로 이동 :

Mj

그리고 다음을 실행하십시오.

:,$g/./exe 'm' 2*line('.')-line('$')-1