인접한 셀의 값을 기반으로 Google 스프레드 시트의 셀 값을 변경하려고합니다. 이 인접한 셀은 이 Quora 답변 의 수식을 사용하여 인접한 셀의 색상에서 값을 가져옵니다 . 따라서 셀의 값은 첫 번째 셀의 색상에서 얻은 16 진 코드를 기반으로 변경되어야합니다. 현재 4 개의 16 진수 값이 있으므로 동일한 셀에 4 개의 다른 IF 문을 넣으려고했기 때문에 값에 따라 값이 변경됩니다.

첫 번째 시도로 수식 구문 분석 오류가 발생했습니다.

=if((J2="#00ff00","Read"), if(j2="#ff0000", "Unread"), if(j2="#ff9900","In Progress"), if(j2="#000000", "Not Applicable"))

if 문을 쉼표로 간단히 구분할 수는 없습니다. 이 스택 오버플로 질문을 기반으로 중첩 된 IF 문 으로이 코드를 시도했습니다.

=if((J2="#00ff00","Read", if(j2="#ff0000", "Unread", if(j2="#ff9900","In Progress",if(j2="#000000", "Not Applicable")))))

또한 수식 구문 분석 오류가 발생합니다.

코드에서 작동하는 동일한 셀에 여러 IF 문을 간단히 포함시킬 수있는 방법이 있습니까?

lookup대신에 사용하십시오 if:

=lookup(B7,
       {"#000000","#00ff00","#ff0000","#ff9900"},
       {"Not applicable", "Read","Unread","In Progress"}
  ) 

두 번째 매개 변수는 정렬 된 목록이어야합니다.

짧은 답변

제공된 예제의 문제점은 괄호입니다. 올바르게 적용하십시오.

설명

IF() 함수에는 두 개의 매개 변수가 있고 선택적으로 세 번째 매개 변수가 있어야합니다.

IF(logical_expression, value_if_true, value_if_false)

특정 문제

• 제공된 첫 번째 예는 외부에 IF()매개 변수가 너무 많다는 것입니다.
• 두 번째 예는 logical_expression바깥 쪽 IF()이 돌아 오지 TRUE않거나FALSE

Google 스프레드 시트에서 함수 매개 변수는 쉼표로 구분됩니다 (또는 스프레드 시트에서 쉼표를 소수점 구분 기호로 사용하는 경우 세미콜론). 괄호를 사용하여 함수 내에 여러 작업과 함수를 묶을 경우이를 포함하는 함수의 매개 변수로 간주됩니다.

일반적인 방법은 내부를 IF()로 설정하는 value_if_false것이지만 여러 가지 방법으로 수행 할 수 있습니다. 와 IF()다른 다른 내부를 추가 하거나 이라고 합니다.value_if_truevalue_if_falseIF() logical test nestingIF() nesting

아래는 3 개 IF()중 2 개가 value_if_false부모의 것을 결정하는 데 사용되는 수식의 예입니다 IF(). 가독성을 위해 괄호 스타일의 여러 줄 및 세로 정렬이 적용됩니다.

 =IF(logical_expression, value_if_true, 
     IF(logical_expression, value_if_true, 
        IF(logical_expression, value_if_true, value_if_false
          )
       )
    )

위 스타일은 Google 스프레드 시트 수식 작성에 사용될 수 있습니다. 수식 디버깅에 유용하다는 것을 알았습니다.

참고

• IF-Google 문서 편집기 도움말

방금 if와 or를 결합하는 방법을 찾았습니다.

예:

=IF(OR(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(AND(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(OR(AND(B3>49,C3>49),AND(B3>49,D3>49),AND(C3>49,D3>49)),”Won”,”Failed”)

예를 들어,

= if(OR(J2="#00ff00",j2="#ff0000",j2="#ff9900"),"True","False")

출처 : Google Doc Spreadsheet에서 IF, AND, OR 논리 함수를 함께 사용 합니다.

예를 들어 IF 문을 중첩시킬 수 있습니다

If(if(if(when all 3 equal true)))

작동 할 것이다

또는

예를 들어 중첩 된 IFAND를 사용할 수 있습니다

IF(AND(AND()))

작동합니다.

당신은 이론과 더 나은 접근법을 제공 받았지만 구체적으로 대답해야합니다.

코드에서 작동하는 동일한 셀에 여러 IF 문을 간단히 포함시킬 수있는 방법이 있습니까?

시도하십시오 :

=if(J2="#00ff00","Read", if(J2="#ff0000", "Unread", if(J2="#ff9900","In Progress",if(J2="#000000", "Not Applicable"))))

즉, 첫 번째 여는 괄호가없고 마지막 닫는 괄호가없는 두 번째 시도입니다.