과도 피드백 아크 세트 (TFAS) : NP- 완료?

얼마 전에 두 세트가 카디널리티와 관련이없는 속성을 충족시키는 가장자리의 2 파티션을 찾고자하는 그래프 문제 에 대한 참조 요청 을 게시 했습니다 . 나는 다음과 같은 문제가 NP-hard라는 것을 증명하려고 노력했다.

토너먼트 가 주어지면, 전 이적 관계를 정의하는 피드백 아크 세트 F ⊆ E 가 G 에 있습니까?$G = (V,E)$$F \subseteq E$$G$

나는 증거를 시도하기위한 구성을 가지고 있지만 그것이 막 다른 길에 빠질 것 같습니다. 그래서 나는 여기에 분명한 것이 빠져 있는지 여부를 물어볼 수 있다고 생각했습니다. 내가 사용한 것과 비슷한 사고 방식으로 창의력을 제한하지 않기 위해 여기에 내 시도를 게시하지 않습니다.

이 문제가 NP-hard입니까? 그렇다면 어떻게 증명해야합니까?

약간의 맥락을 추가하기 위해 다음은 전이 피드백 아크 세트가없는 그래프의 구성입니다. 이 구성에는 다음 가젯 그래프를 사용합니다.

이 토너먼트에는 다음과 같은 속성이 있습니다 (프로그램을 사용하여 확인했지만 공식적으로 증명하지 않았습니다).

• (2,7)이 주어진 TFAS에 없으면 (1,3)은
• 주어진 TFAS에 (5,1)이 있으면 (3,6)도
• (7,3)이 주어진 TFAS에 있으면 (5,1)은 그렇지 않습니다

또는 약간 남용하는 술어 논리 표기법 :

• $\neg (2,7) \rightarrow (1,3)$
• $(5,1) \rightarrow (3,6)$
• $(7,3) \rightarrow \neg (5,1)$

각 의미에 대해 두 모서리가 쌍으로 분리되어 있으므로 다음과 같은 구성 작업이 수행됩니다.

$A$

TFAS없이 그래프를보고하지 않는 짧은 clingo 프로그램을 실행했지만 버그가있었습니다. 나는 그것을 고쳤고 이제는 TFAS가없는 그래프가 n = 8 이하인지 확인합니다. n = 9 인 경우 다음을 찾습니다.

is_edge(edge(2,3)) is_edge(edge(1,4)) is_edge(edge(2,4)) is_edge(edge(3,5)) is_edge(edge(4,5)) is_edge(edge(1,6)) is_edge(edge(2,6)) is_edge(edge(3,6)) is_edge(edge(5,6)) is_edge(edge(1,7)) is_edge(edge(4,7)) is_edge(edge(5,7)) is_edge(edge(6,7)) is_edge(edge(1,8)) is_edge(edge(3,8)) is_edge(edge(4,8)) is_edge(edge(5,9)) is_edge(edge(6,9)) is_edge(edge(7,9)) is_edge(edge(2,1)) is_edge(edge(3,1)) is_edge(edge(4,3)) is_edge(edge(5,1)) is_edge(edge(5,2)) is_edge(edge(6,4)) is_edge(edge(7,2)) is_edge(edge(7,3)) is_edge(edge(8,2)) is_edge(edge(8,5)) is_edge(edge(8,6)) is_edge(edge(8,7)) is_edge(edge(9,1)) is_edge(edge(9,2)) is_edge(edge(9,3)) is_edge(edge(9,4)) is_edge(edge(9,8))

다음은 (고정) 인코딩입니다.

% tfas.asp
#show is_edge/1.
vertex(1..n).

opp_edges(edge(A,B),edge(B,A)) :- vertex(A), vertex(B), A < B.
possible_edge(E1;E2) :- opp_edges(E1,E2).

{is_edge(E1); is_edge(E2)} = 1 :- opp_edges(E1, E2).
ntfas(E) :- possible_edge(E), not is_edge(E).
ntfas(edge(X, X)) :- vertex(X).

tfas(E) | fs(E) :- is_edge(E).
ntfas(E) :- fs(E).

broken :- ntfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- fs(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), fs(edge(Y, Z)), is_edge(edge(Y, Z)).
broken :- reachable(X, X).

tfas(E) :- broken, possible_edge(E).
fs(E) :- broken, possible_edge(E).
:- not broken.

clingo -c n=7 tfas.asp(clingo 4.2.1 사용)으로 실행하십시오.

(n = 7은 정확히 7 개의 꼭짓점의 그래프를 나타냅니다)

7 개의 꼭짓점에 TFAS가없는 그래프가있는 경우에만 만족스러운 결과를 반환해야합니다.

좋아, 나는 @ G.Bach가 어떤 그래프를 설명하고 clingo로 그것을 코딩했는지 알아 냈다. 34-vertex 토너먼트 그래프 G.Bach가 설명하고 있습니다 (접지 그래프 설명도 첨부했습니다).

그런 다음 해당 그래프에서 clingo를 실행했으며 가장자리가 241 인 TFAS를 찾았다 고 주장했습니다. 그러나 그래프 인코딩에서 실수를했습니다. 나는 실수를 고쳤고 clingo는 이제 만족할 수 없다고보고했다 (즉, TFAS가 없다).

그래프에서 TFAS를 찾는 프로그램은 다음과 같습니다.

{tfas(E)} :- is_edge(E).
:- not tfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- not tfas(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), not tfas(edge(Y, Z)), is_edge(edge(Y, Z)).
:- reachable(X, X).

tfas_count(N) :- N = #count{tfas(E) : tfas(E)}.

#show tfas/1.
#show tfas_count/1.

다음은 G.Bach의 그래프를 생성하기위한 (업데이트 된) 프로그램입니다. 그래프가 올바른 토너먼트 그래프인지 확인하기 위해 끝에 표시기를 추가했습니다.

gadget_vertex(0..7).

gadget_edge(0,1).
gadget_edge(0,2).
gadget_edge(0,3).
gadget_edge(0,4).
gadget_edge(1,2).
gadget_edge(1,3).
gadget_edge(1,6).
gadget_edge(1,7).
gadget_edge(2,3).
gadget_edge(2,4).
gadget_edge(2,5).
gadget_edge(2,7).
gadget_edge(3,4).
gadget_edge(3,5).
gadget_edge(3,6).
gadget_edge(4,1).
gadget_edge(4,5).
gadget_edge(4,6).
gadget_edge(4,7).
gadget_edge(5,0).
gadget_edge(5,1).
gadget_edge(5,6).
gadget_edge(6,0).
gadget_edge(6,2).
gadget_edge(6,7).
gadget_edge(7,0).
gadget_edge(7,3).
gadget_edge(7,5).

special_edge(a;b;c;d;e).

forces(a,b).
forces(b,c).
forcesn(c,a).
nforces(a,d).
forces(d,e).
forces(e,a).

relates(A,B) :- forces(A,B).
relates(A,B) :- nforces(A,B).
relates(A,B) :- forcesn(A,B).

is_se_pair(se_pair(A,B)) :- relates(A,B).
vertex_name(v(V,P)) :- gadget_vertex(V), is_se_pair(P).

matches(from(A), v(5, se_pair(A,B))) :- forces(A,B).
matches(to(A), v(1, se_pair(A,B))) :- forces(A,B).
matches(from(B), v(3, se_pair(A,B))) :- forces(A,B).
matches(to(B), v(6, se_pair(A,B))) :- forces(A,B).

matches(from(A), v(2, se_pair(A,B))) :- nforces(A,B).
matches(to(A), v(7, se_pair(A,B))) :- nforces(A,B).
matches(from(B), v(1, se_pair(A,B))) :- nforces(A,B).
matches(to(B), v(3, se_pair(A,B))) :- nforces(A,B).

matches(from(A), v(7, se_pair(A,B))) :- forcesn(A,B).
matches(to(A), v(3, se_pair(A,B))) :- forcesn(A,B).
matches(from(B), v(5, se_pair(A,B))) :- forcesn(A,B).
matches(to(B), v(1, se_pair(A,B))) :- forcesn(A,B).

same_vertex(V, V) :- vertex_name(V).
same_vertex(M, N; N, M) :- matches(X, M), matches(X, N).

already_found(v(Y,N2)) :- vertex_name(v(X,N1)), same_vertex(v(X,N1),v(Y,N2)), N1 < N2.
vertex(V) :- vertex_name(V), not already_found(V).

named_gadget_edge(edge(v(X,SE),v(Y,SE))) :- gadget_edge(X,Y), is_se_pair(SE).
from_gadget_edge_named(edge(A, B), edge(C,D)) :- named_gadget_edge(edge(C,D)), same_vertex(A,C), same_vertex(B,D), vertex(A), vertex(B).
from_gadget_edge(edge(A,B)) :- from_gadget_edge_named(edge(A,B),edge(C,D)).
is_edge(E) :- from_gadget_edge(E).
is_edge(edge(A,B)) :- vertex(A), vertex(B), A < B, not from_gadget_edge(edge(B,A)).

vertex_count(VN) :- VN = #count{vertex(V) : vertex(V)}.
edge_count(EN) :- EN = #count{is_edge(E) : is_edge(E)}.

#show vertex_count/1.
#show edge_count/1.

bidirectional :- is_edge(edge(A,B)), is_edge(edge(B,A)).
phantom_vertex :- is_edge(edge(A,B)), not vertex(A).
phantom_vertex :- is_edge(edge(A,B)), not vertex(B).
incomplete :- vertex(A), vertex(B), not is_edge(edge(A,B)), not is_edge(edge(B,A)), A != B.

#show bidirectional/0.
#show phantom_vertex/0.
#show incomplete/0.

SWAG 추측 [아무것보다 나은 것이 있습니까?] :

$G = (V,E)$$F \subseteq E$$G$$O(1)$

^{참고 : 슛 다운 카운터 예제를 환영합니다! 지금까지 아무도 주어지지 않은 것 같습니다. 특정 그래프 클래스와 관련된 가장자리 방향의 패턴을 관찰하는 것이 더 좋습니다. 또는 더 많은 동기 부여 또는 기존 문학과의 연계. 증거와 반박 (Lakatos) 의 스타일로 제공됩니다 ... 또한, 아직 그다지 관련이없는 외설적 인 문제로 보이므로 경험적으로 연구하는 것이 좋습니다 ....}