일반화 된 선형 모형에서 예상되는 잔차 분포는 무엇입니까?

일반화 된 선형 모델을 수행하고 있는데 일반 모델과 다른 패밀리를 지정해야합니다.

• 예상되는 잔차 분포는 무엇입니까?
• 예를 들어, 잔차가 정상적으로 분포되어야합니까?

What is the expected distribution of residuals?

일반적으로 대답하기 어려운 방식으로 모델에 따라 다릅니다.

For example, should the residuals be distributed normally?

일반적으로 아닙니다.

피어슨 잔차, Anscombe 잔차, (조정 된) 이탈 잔차 등보다 대칭 적이거나 심지어 "정상"(예 : 가우시안) 인 GLM 잔차 설계를 중심으로 한 전체 코티지 산업이 있습니다. 예를 들어 James W의 6 장을 참조하십시오. Hardin과 Joseph M. Hilbe (2007) "일반화 된 선형 모델 및 확장"제 2 판. TX, College Station : Stata Press. 종속 변수가 불연속적인 경우 (지표 변수 또는 개수) 잔차의 예상 분포를 정확히 가우스로 만드는 것은 매우 어렵습니다.

모델이 참이라고 가정하여 새 데이터를 반복적으로 시뮬레이션하고 시뮬레이션 된 데이터를 사용하여 모델을 추정하고 잔차를 계산 한 다음 실제 잔차를 시뮬레이션 잔차와 비교하는 것이 가능합니다. Stata에서는 다음과 같이합니다.

sysuse nlsw88, clear
glm wage i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)

// collect which observations were used in estimation and the predicted mean
gen byte touse = e(sample)
predict double mu if touse

// predict residuals
predict resid if touse, anscombe

// prepare variables for plotting a cumulative distribution function
cumul resid, gen(c)

// collect the graph command in the local macro `graph'
local graph "twoway"

// create 19 simulations:
gen ysim = .
forvalues i = 1/19 {
    replace ysim = rpoisson(mu) if touse
    glm ysim i.union grade c.ttl_exp##c.ttl_exp, link(log) family(poisson)
    predict resid`i' if touse, anscombe
    cumul resid`i', gen(c`i')
    local graph "`graph' line c`i' resid`i', sort lpattern(solid) lcolor(gs8) ||"
}
local graph "`graph' line c resid, sort lpattern(solid) lcolor(black) "

// display the graph
`graph' legend(order(20 "actual residuals" 1 "simulations"))