모든 MKV 파일 찾기 및 모든 자막 삭제

나는 현재 Windows 프로그램을보고있다. mkvmerge . 모든 경로에서 재귀 적으로 모든 MKV 파일을 찾은 배치 파일을 만들고 MKV 파일에서 자막이있는 경우 모든 자막을 제거하고 자막이 제거 된 원본 MKV 파일을 모두 삭제합니다.

나는 약 2 시간의 인터넷 검색을했고, 다음과 같은 것을 쓸 수 있어야한다는 것을 알게되었다.

FOR /F "delims=*" %%A IN ('dir /b *.MKV') DO "C:\mkvmerge.exe" -o "fixed_%%A" -a 4 -s 7 --compression -1:none "%%A"

나는 여전히 노력하고 있지만, 누군가가 나에게 약간의 도움을 줄 수 있다면, 정말로 감사 할 것입니다.

다음과 같이 저장하십시오. DelMKVSubs.bat 같은 디렉토리에있다. mkvmerge.exe 에 있습니다. 루트 폴더 변수를 요구 사항에 따라 배치 파일을 실행하십시오.

@echo off
cls
set rootfolder=C:\
echo Enumerating all MKVs under %rootfolder%
echo.
for /r %rootfolder% %%a in (*.mkv) do (
    for /f %%b in ('mkvmerge -i "%%a" ^| find /c /i "subtitles"') do (
        if [%%b]==[0] (
            echo "%%a" has no subtitles
        ) else (
            echo.
            echo "%%a" has subtitles
            mkvmerge -q -o "%%~dpna (No Subs)%%~xa" -S "%%a"
            if errorlevel 1 (
                echo Warnings/errors generated during remuxing, original file not deleted
            ) else (
                del /f "%%a"
                echo Successfully remuxed to "%%~dpna (No Subs)%%~xa", original file deleted
            )
            echo.
        )
    )
)

배치 파일은 쉽게 이해할 수 있어야하지만 다음과 같은 개요가 있습니다.

1. 그것은 사용 for /r 재귀 적으로 검색 %rootfolder% 모든 MKV

2. 그런 다음 실행됩니다. mkvmerge -i 각 MKV에 자막 트랙이 있는지 확인

3. MKV에 자막 트랙이 포함되어 있으면 MKV가 실행됩니다. mkvmerge -S 그런 모든 트랙을 건너 뛰면서 파일을 재조정합니다.

4. 마지막으로 mkvmerge의 종료 코드를 확인하고 errorlevel )는 경고 / 오류없이 0을 나타내며 원본 파일을 삭제합니다

자세한 내용은 mkvmerge 문서 그리고 또한 for /?, if /? 명령 프롬프트에서.

고마워, 카란. 나에게도 매우 유용했다. 스크립트를 수정하여 보관하려는 자막에 대한 언어 (3LC (eng, ned, swe 등)로 지정)를 선택할 수 있도록했습니다. 또한 입력 파일이 삭제 된 부분을 제거하고 출력 파일에 접미사를 추가하기로 결정했습니다.

내 버전은 다음과 같습니다.

:: remux all mkvs under a certain subfolder with all subitles
:: but those as specified by %language% parameter removed.

@echo off
setlocal enabledelayedexpansion

:: set your variables here
set rootfolder="C:\temp\New folder"
set language=eng
set suffix= (eng sub)

:: do the remuxing
echo Remuxing all mkvs in %rootfolder% and its subfolders.
for /r %rootfolder% %%a in (*.mkv) do (
    set subs=
    set mkv=%%a
    for /f "tokens=3 delims=: " %%b in ('mkvmerge -I "%%a" ^| findstr /i /r ".*subtitles.*language:%language%.*"') do (
        set subs=!subs!,%%b
    )
    for /f "tokens=*delims=," %%c in ("!subs!") do (
        set subs=%%c
    )
    if not exist "%%~dpna%suffix%%%~xa" if not "!subs!"=="" (
        mkvmerge -q -o "%%~dpna%suffix%%%~xa" -s !subs! "%%a"
        if errorlevel 1 (
            echo Warnings/errors generated during remuxing of "%%a".
        ) else (
            echo Successfully remuxed to "%%~dpna (eng subs)%%~xa".
        )
    ) else (
        echo Input file "%%a" has no subtitles in %language% or output file "%%~dpna%suffix%%%~xa" already exists. Skipping this file.
    )
)
pause