모든 연속 복제본 삭제

다음과 같은 파일이 있습니다.

Move to 230.00
Hold
Hold
Hold
Hold
Hold
Hold
Move to 00.00
Hold 
Hold 
Hold 
Hold 
Hold 
FooBar
Hold 
Spam
Hold

다음과 같이 표시하고 싶습니다.

Move to 230.00
Hold
Move to 00.00
Hold 
FooBar
Hold
Spam
Hold

나는 vim이 빨리 이것을 할 수있는 방법이 있어야한다고 확신하지만, 어떻게 내 머리를 감쌀 수는 없습니다. 이것이 매크로의 힘을 넘어서서 vimscript가 필요합니까?

또한 "홀드"의 각 블록에 동일한 매크로를 적용해야해도 괜찮습니다. 전체 파일을 가져 오는 단일 매크로 일 필요는 없지만 훌륭합니다.

다음 명령이 작동해야한다고 생각합니다.

 :%s/^\(.*\)\(\n\1\)\+$/\1/

설명 :

전체 파일에서 치환 명령을 사용하여 다음과 같이 변경 pattern합니다 string.

:%s/pattern/string/

여기에 pattern있습니다 ^\(.*\)\(\n\1\)\+$및 string입니다 \1.

pattern 다음과 같이 분류 할 수 있습니다.

^\(subpattern1\)\(subpattern2\)\+$

^그리고 $각각 라인의 시작과 라인의 끝과 일치.

\(및 \)둘러싸는 데 사용되는 subpattern1우리가 특별한 번호로 나중에 참조 할 수 있도록 \1.
그것들은 또한 subpattern2우리가 수량 화기로 1 회 이상 반복 할 수 있도록 둘러싸는 데 사용됩니다 \+.

subpattern1은 .*
.개행을 제외한 모든 문자와 일치하는 메타 문자이며 *마지막 문자 0, 1 회 이상 일치하는 수량 자입니다.
따라서 .*줄 바꿈이없는 텍스트와 일치합니다.

subpattern2되고 \n\1
\n새로운 라인과 일치 \1먼저 내부 유사한 것과 같은 텍스트와 일치하는 \(, \)여기를한다 subpattern1.

따라서 다음 pattern과 같이 읽을 수 있습니다.
줄의 시작 ( ^), 새 줄이없는 텍스트 ( ), .*새 줄 ( \n), 같은 텍스트 ( \1), 뒤의 두 개가 한 번 이상 반복됩니다 ( \+) 마지막으로 줄의 끝 ( $) .

pattern일치하는 곳 (동일한 줄의 블록)이면 대체 명령 string이 여기있는 곳 \1(블록의 첫 번째 줄)으로 바꿉니다 .

파일에서 아무것도 변경하지 않고 어떤 행 블록이 영향을 받는지 확인하려면 hlsearch옵션을 활성화 n하고 명령 끝에 대체 플래그를 추가 할 수 있습니다 .

:%s/^\(.*\)\(\n\1\)\+$/\1/n

보다 세밀한 제어를 위해 c대체 플래그를 대신 추가하여 각 라인 블록을 변경하기 전에 확인을 요청할 수도 있습니다 .

:%s/^\(.*\)\(\n\1\)\+$/\1/c

대체 명령 읽기에 대한 자세한 내용은 :help :s,
대체 플래그 :help s_flags,
다양한 메타 문자 및 한정사가 읽기 :help pattern-atoms,
및 위해 정력에 정규 표현식 읽기 이 .

편집 : 와일드 카드$ 끝에 에를 추가하여 명령의 문제를 해결했습니다 pattern.

또한 BloodGain 은 더 짧고 읽기 쉬운 동일한 명령 버전을 가지고 있습니다.

다음을 시도하십시오 :

:%s;\v^(.*)(\n\1)+$;\1;

saginaw의 답변 과 마찬가지로 Vim의 : substitute 명령을 사용합니다. 그러나 가독성을 향상시키기 위해 몇 가지 추가 기능을 활용합니다.

1. Vim에서는 백 슬래시 ( \ ), 큰 따옴표 ( " ) 또는 파이프 ( | )를 제외한 영숫자가 아닌 ASCII 문자를 사용하여 일치 / 바꾸기 / 플래그 텍스트를 나눌 수 있습니다. 여기서는 세미콜론 ( ; )을 선택했습니다 . 다른 것을 고르시 오.
2. Vim은 정규식에 "마법"설정을 제공하므로 문자가 백 슬래시 이스케이프를 요구하지 않고 특수한 의미로 해석됩니다. 이 기능은 자세한 정보를 줄이는 데 도움이되며 "nomagic"기본값보다 더 일관성이 있습니다. \v"매우 마술"로 시작 하거나 영숫자 ( A-z0-9 ) 및 밑줄 ( _ )을 제외한 모든 문자 는 특별한 의미를 갖습니다.

구성 요소의 의미는 다음과 같습니다.

전체 파일에 대한 %

님의 대체

; 대체 문자열을 시작

\ v "매우 마술"

^ 줄의 시작

. (*) 0 이상의 임의의 문자 (그룹 1)

(\ n \ 1) + 개행 다음에 (그룹 1 일치 텍스트), 1 회 이상 (그룹 2)

$ 줄 끝 (또는이 경우 다음 문자는 개행 문자 라고 생각하십시오 )

; 문자열 교체 시작

\ 1 그룹 1 일치 텍스트

; 명령의 끝 또는 시작 플래그

뿐만 아니라 인접한 모든 동일한 줄을 제거 Hold하려면 다음과 같은 외부 필터를 사용하여 매우 쉽게 수행 할 수 있습니다 vim.

:%!uniq (유닉스 환경에서).

에서 직접하고 싶다면 vim실제로 매우 까다 롭습니다. 나는 방법이 있다고 생각하지만 일반적인 경우 100 % 기능을 만드는 것은 매우 까다 롭고 아직 모든 버그를 해결하지 못했습니다.

그러나이 특정 경우 중복되지 않은 다음 줄이 같은 문자로 시작하지 않는 것을 시각적으로 볼 수 있으므로 다음을 사용할 수 있습니다.

:+,./^[^H]/-d

은 +전류 선 후 라인을 의미한다. . 현재 줄을 나타냅니다. 는 /^[^H]/-(전 라인을 의미 -H.로 시작하지 않는 다음 라인)

그런 다음 d가 삭제됩니다.

Vim 기반 답변 :

:%s/\(^.*\n\)\1\{1,}/\1

= 같은 줄로 모든 줄 다음에 적어도 한 번은 그 자체를 바꿉니다 .

Vim 7.4.218 이상을 가정하면 하나 더 :

function! s:Uniq(line1, line2)
    let cursor = getcurpos()
    let lines = uniq(getline(a:line1, a:line2))
    if setline(a:line1, lines) == 0 && len(lines) <= a:line2 - a:line1
        silent execute (a:line1 + len(lines)) . ',' . a:line2 . 'd _'
    endif
    call setpos('.', cursor)
endfunction

command! -range=% Uniq call <SID>Uniq(<line1>, <line2>)

그러나 이것이 다른 솔루션보다 반드시 낫지는 않습니다.

다음은 Preben Gulberg와 Piet Delport 의 오래된 (2003) vim (golf) 기반 솔루션 입니다.

• 뿌리는 %g/^\v(.*)\n\1$/d
• 다른 솔루션과 달리 함수 로 캡슐화 되었으므로 검색 레지스터 나 명명되지 않은 레지스터를 수정하지 않습니다.
• 또한 사용법을 단순화하기 위해 명령으로 캡슐화되었습니다.
  • :Uniq(와 동일 :%Uniq),
  • :1,Uniq (버퍼의 시작부터 현재 행까지)
  • 시각적으로 선 + 적중 선택 :Uniq<cr>(vim으로 확장 :'<,'>Uniq)
  • 등 ( :h range)

코드는 다음과 같습니다.

command! -range=% -nargs=0 Uniq <line1>,<line2>call s:EmuleUniq()

function! s:EmuleUniq() range
  let l1 = a:firstline
  let l2 = a:lastline
  if l1 < l2
    " Note the "-" to avoid spilling over the end of the range
    " Note also the use of ":delete", along with the black hole register "_"
    silent exe l1.','l2.'-g/^\(.*\)\n\1$/d _'

    call histdel('search', -1)          " necessary
    " let @/ = histget('search', -1)    " useless within a function
  endif
endfunction

참고 : 첫 시도는 다음과 같습니다.

" Version1 from: Preben 'Peppe' Guldberg <peppe {at} xs4all {dot} nl>
" silent exe l1 . ',' . (l2 - 1) . 's/^\(.*\)\%(\n\%<' . (l2 + 1)
      " \ . 'l\1$\)\+/\1/e'

" Version from: Piet Delport <pjd {at} 303.za {dot} net>
" silent exe l1.','l2.'g/^\%<'.l2.'l\(.*\)\n\1$/d'